print_table utility procedure

Found this store procedure on Tom Kyte’s site which can be used to print columns in a table row wise, click on the link to read the discussion on it.

The store procedure takes 2 parameters (1) – SQL statement to be executed, (2) – Date format to printed
Code:
create or replace
procedure print_table
( p_query in varchar2,
p_date_fmt in varchar2 default 'dd-mon-yyyy hh24:mi:ss')
-- this utility is designed to be installed ONCE in a database and used
-- by all. Also, it is nice to have roles enabled so that queries by
-- DBA's that use a role to gain access to the DBA_* views still work
-- that is the purpose of AUTHID CURRENT_USER
AUTHID CURRENT_USER
is
l_theCursor integer default dbms_sql.open_cursor;
l_columnValue varchar2(4000);
l_status integer;
l_descTbl dbms_sql.desc_tab;
l_colCnt number;
l_cs varchar2(255);
l_date_fmt varchar2(255);

-- small inline procedure to restore the sessions state
-- we may have modified the cursor sharing and nls date format
-- session variables, this just restores them
procedure restore
is
begin
if ( upper(l_cs) not in ( 'FORCE','SIMILAR' ))
then
execute immediate
'alter session set cursor_sharing=exact';
end if;
if ( p_date_fmt is not null )
then
execute immediate
'alter session set nls_date_format=''' || l_date_fmt || '''';
end if;
dbms_sql.close_cursor(l_theCursor);
end restore;
begin
-- I like to see the dates print out with times, by default, the
-- format mask I use includes that. In order to be “friendly”
-- we save the date current sessions date format and then use
-- the one with the date and time. Passing in NULL will cause
-- this routine just to use the current date format
if ( p_date_fmt is not null )
then
select sys_context( 'userenv', 'nls_date_format' )
into l_date_fmt
from dual;

execute immediate
'alter session set nls_date_format=''' || p_date_fmt || '''';
end if;

-- to be bind variable friendly on this ad-hoc queries, we
-- look to see if cursor sharing is already set to FORCE or
-- similar, if not, set it so when we parse — literals
-- are replaced with binds
if ( dbms_utility.get_parameter_value
( 'cursor_sharing', l_status, l_cs ) = 1 )
then
if ( upper(l_cs) not in ('FORCE','SIMILAR'))
then
execute immediate
'alter session set cursor_sharing=force';
end if;
end if;

-- parse and describe the query sent to us. we need
-- to know the number of columns and their names.
dbms_sql.parse( l_theCursor, p_query, dbms_sql.native );
dbms_sql.describe_columns( l_theCursor, l_colCnt, l_descTbl );

-- define all columns to be cast to varchar2's, we
-- are just printing them out
for i in 1 .. l_colCnt loop
if ( l_descTbl(i).col_type not in ( 113 ) )
then
dbms_sql.define_column
(l_theCursor, i, l_columnValue, 4000);
end if;
end loop;

-- execute the query, so we can fetch
l_status := dbms_sql.execute(l_theCursor);

-- loop and print out each column on a separate line
-- bear in mind that dbms_output only prints 255 characters/line
-- so we'll only see the first 200 characters by my design…
while ( dbms_sql.fetch_rows(l_theCursor) > 0 )
loop
for i in 1 .. l_colCnt loop
if ( l_descTbl(i).col_type not in ( 113 ) )
then
dbms_sql.column_value
( l_theCursor, i, l_columnValue );
dbms_output.put_line
( rpad( l_descTbl(i).col_name, 30 )
|| ': ' ||
substr( l_columnValue, 1, 200 ) );
end if;
end loop;
dbms_output.put_line( '—————–' );
end loop;

-- now, restore the session state, no matter what
restore;
exception
when others then
restore;
raise;
end;
/

Sample Output:
SQL> exec print_table('select * from dba_users where username = ''SYSTEM''');
USERNAME : SYSTEM
USER_ID : 5
PASSWORD : D4DF7931AB130E37
ACCOUNT_STATUS : OPEN
LOCK_DATE :
EXPIRY_DATE :
DEFAULT_TABLESPACE : SYSTEM
TEMPORARY_TABLESPACE : TEMP
CREATED : 12-aug-2009 21:12:59
PROFILE : DEFAULT
INITIAL_RSRC_CONSUMER_GROUP : SYS_GROUP
EXTERNAL_NAME :
—————–

2 thoughts on “print_table utility procedure

  1. When I execute print_table (exec print_table(‘select * from mytable’), I get the following message, but no output: “anonymous block completed”
    I can’t find this message description anywhere. What does it mean, and what am I missing? Thanks.

    • Hi Roy,

      Are you running this through SQL*Plus? If so you need to set “set serveroutput on” before you execute this store procedure.

      Sample run:
      SQL> set serveroutput on
      SQL> exec print_table(‘select * from dba_users where username = ”SYS”’);
      USERNAME : SYS
      USER_ID : 0
      ACCOUNT_STATUS : OPEN
      LOCK_DATE :
      EXPIRY_DATE :
      DEFAULT_TABLESPACE : SYSTEM
      TEMPORARY_TABLESPACE : TEMP
      CREATED : 30-dec-2003 10:05:58
      PROFILE : DEFAULT
      INITIAL_RSRC_CONSUMER_GROUP : SYS_GROUP
      EXTERNAL_NAME :

      I have updated the script as the comments showed up as single dash on the page even though it has double dash.

      Let me know if it worked

Leave a Reply

Fill in your details below or click an icon to log in:

WordPress.com Logo

You are commenting using your WordPress.com account. Log Out / Change )

Twitter picture

You are commenting using your Twitter account. Log Out / Change )

Facebook photo

You are commenting using your Facebook account. Log Out / Change )

Google+ photo

You are commenting using your Google+ account. Log Out / Change )

Connecting to %s